Mirrors/ScreenPlay
Mirrors/ScreenPlay
1
0
Fork 0
mirror of https://gitlab.com/kelteseth/ScreenPlay.git synced 2024-11-22 10:42:29 +01:00
Code Issues Projects Releases Activity

Remove old project files

Browse Source
This commit is contained in:
Elias Steurer 2020-05-01 16:46:09 +02:00
parent 1cca1d028f
commit bd77099c06
7 changed files with 0 additions and 295 deletions
Show Stats Download Patch File Download Diff File Expand all files Collapse all files

17
ScreenPlay.pro
View File

@ -1,17 +0,0 @@
TEMPLATE = subdirs
SUBDIRS += \
ScreenPlay/ScreenPlay.pro \
ScreenPlaySDK/ScreenPlaySDK.pro \
ScreenPlayWallpaper/ScreenPlayWallpaper.pro \
ScreenPlayWidget/ScreenPlayWidget.pro \
Common/stomt-qt-sdk/sdk/stomt-qt-sdk.pro \
ScreenPlayWallpaper.depends = ScreenPlaySDK
ScreenPlayWidget.depends = ScreenPlaySDK
win32 {
SUBDIRS += \
ScreenPlaySysInfo/ScreenPlaySysInfo.pro \
}

133
ScreenPlay/ScreenPlay.pro
View File

@ -1,133 +0,0 @@
TEMPLATE = app
QT += qml quick widgets quickcontrols2 core webengine
CONFIG += c++17
TARGETPATH = ScreenPlay
include($$PWD/../Common/qt-google-analytics/qt-google-analytics.pri)
!unix {
include($$PWD/../Common/qt-breakpad/qt-breakpad.pri)
}
ICON = favicon.ico
DEFINES += QT_DEPRECATED_WARNINGS
GIT_VERSION = $$system(git describe --always)
DEFINES += GIT_VERSION=\\\"$$GIT_VERSION\\\"
DISTFILES += \
$$PWD/favicon.ico \
RESOURCES += \
$$PWD/Resources.qrc
SOURCES += \
$$PWD/main.cpp \
$$PWD/app.cpp \
$$PWD/src/createimportvideo.cpp \
$$PWD/src/installedlistmodel.cpp \
$$PWD/src/monitorlistmodel.cpp \
$$PWD/src/screenplaywallpaper.cpp \
$$PWD/src/screenplaywidget.cpp \
$$PWD/src/settings.cpp \
$$PWD/src/profilelistmodel.cpp \
$$PWD/src/installedlistfilter.cpp \
$$PWD/src/sdkconnector.cpp \
$$PWD/src/projectsettingslistmodel.cpp \
$$PWD/src/screenplaymanager.cpp \
$$PWD/src/util.cpp \
$$PWD/src/create.cpp
TRANSLATIONS = \
$$PWD/translations/ScreenPlay_en.ts \
$$PWD/translations/ScreenPlay_de.ts \
$$PWD/translations/ScreenPlay_ru.ts \
$$PWD/translations/ScreenPlay_es.ts \
$$PWD/translations/ScreenPlay_fr.ts \
$$PWD/translations/ScreenPlay_ko.ts \
$$PWD/translations/ScreenPlay_vi.ts \
HEADERS += \
$$PWD/app.h \
$$PWD/src/globalvariables.h \
$$PWD/src/createimportvideo.h \
$$PWD/src/installedlistmodel.h \
$$PWD/src/monitorlistmodel.h \
$$PWD/src/screenplaywallpaper.h \
$$PWD/src/screenplaywidget.h \
$$PWD/src/settings.h \
$$PWD/src/profilelistmodel.h \
$$PWD/src/profile.h \
$$PWD/src/projectfile.h \
$$PWD/src/installedlistfilter.h \
$$PWD/src/sdkconnector.h \
$$PWD/src/projectsettingslistitem.h \
$$PWD/src/projectsettingslistmodel.h \
$$PWD/src/screenplaymanager.h \
$$PWD/src/util.h \
$$PWD/src/create.h
INCLUDEPATH += \
$$PWD/src/\
CONFIG(debug, debug|release) {
install_assets.path = $${OUT_PWD}/assets/fonts
} else {
install_assets.path = $${OUT_PWD}/assets/fonts
}
install_assets.files += $$PWD/assets/fonts/NotoSansCJKkr-Regular.otf
win32: ARCH_OS = x64-windows
unix:!macx { ARCH_OS = x64-linux}
macx: ARCH_OS = x64-osx
CONFIG(debug, debug|release){
ARCH_OS_BUILD = $$ARCH_OS/debug
} else {
ARCH_OS_BUILD = $$ARCH_OS
}
INCLUDEPATH += $$PWD/../Common/vcpkg/installed/$$ARCH_OS/include
DEPENDPATH += $$PWD/../Common/vcpkg/installed/$$ARCH_OS/include
win32 {
RC_ICONS += favicon.ico
CONFIG(debug, debug|release) {
install_it.path = $${OUT_PWD}/debug/
} else {
install_it.path = $${OUT_PWD}/release/
}
LIBS += -luser32
LIBS += -L$$PWD/../Common/vcpkg/installed/x64-windows/lib/ -llibzippp
install_it.files += $$PWD/../Common/vcpkg/installed/$$ARCH_OS_BUILD/bin/zip.dll \
$$PWD/../Common/vcpkg/installed/$$ARCH_OS_BUILD/bin/zlibd1.dll \
$$PWD/../Common/vcpkg/installed/$$ARCH_OS_BUILD/bin/libzippp.dll \
$$PWD/../Common/vcpkg/installed/$$ARCH_OS_BUILD/bin/bz2d.dll \
$$PWD/../Common/vcpkg/installed/$$ARCH_OS_BUILD/bin/libcrypto-1_1-x64.dll \
$$PWD/../Common/vcpkg/installed/$$ARCH_OS_BUILD/bin/libssl-1_1-x64.dll \
}
unix {
CONFIG(debug, debug|release){
#lbz2d uses d
LIBS += -L$$PWD/../Common/vcpkg/installed/$$ARCH_OS_BUILD/lib/ -llibzippp -lzip -lbz2d -lz -lcrypto -lssl -ldl
} else {
LIBS += -L$$PWD/../Common/vcpkg/installed/$$ARCH_OS_BUILD/lib/ -llibzippp -lzip -lbz2 -lz -lcrypto -lssl -ldl
}
}
INSTALLS += install_it install_assets

7
ScreenPlaySDK/ScreenPlaySDK.pri
View File

@ -1,7 +0,0 @@
SOURCES += \
$$PWD/screenplay-sdk_plugin.cpp \
$$PWD/screenplaysdk.cpp
HEADERS += \
$$PWD/screenplay-sdk_plugin.h \
$$PWD/screenplaysdk.h

35
ScreenPlaySDK/ScreenPlaySDK.pro
View File

@ -1,35 +0,0 @@
TEMPLATE = lib
TARGET = ScreenPlaySDK
TARGET = $$qtLibraryTarget($$TARGET)
QT += qml quick
CONFIG += plugin c++17
uri = ScreenPlay.ScreenPlaySDK
# Input
SOURCES += \
$$PWD/screenplay-sdk_plugin.cpp \
$$PWD/screenplaysdk.cpp
HEADERS += \
$$PWD/screenplay-sdk_plugin.h \
$$PWD/screenplaysdk.h
DISTFILES = qmldir
!equals(_PRO_FILE_PWD_, $$OUT_PWD) {
copy_qmldir.target = $$OUT_PWD/qmldir
copy_qmldir.depends = $$_PRO_FILE_PWD_/qmldir
copy_qmldir.commands = $(COPY_FILE) \"$$replace(copy_qmldir.depends, /, $$QMAKE_DIR_SEP)\" \"$$replace(copy_qmldir.target, /, $$QMAKE_DIR_SEP)\"
QMAKE_EXTRA_TARGETS += copy_qmldir
PRE_TARGETDEPS += $$copy_qmldir.target
}
qmldir.files = qmldir
installPath = $$[QT_INSTALL_QML]/$$replace(uri, \\., /)
qmldir.path = $$installPath
target.path = $$installPath
INSTALLS += target qmldir

42
ScreenPlaySysInfo/ScreenPlaySysInfo.pro
View File

@ -1,42 +0,0 @@
TEMPLATE = lib
TARGET = ScreenPlaySysInfo
QT += qml quick
CONFIG += plugin c++17
TARGET = $$qtLibraryTarget($$TARGET)
uri = ScreenPlay.Sysinfo
SOURCES += \
screenplaysysinfo_plugin.cpp \
sysinfo.cpp \
cpu.cpp \
ram.cpp \
storage.cpp
HEADERS += \
screenplaysysinfo_plugin.h \
sysinfo.h \
cpu.h \
ram.h \
mathhelper.h \
storage.h
DISTFILES = qmldir
!equals(_PRO_FILE_PWD_, $$OUT_PWD) {
copy_qmldir.target = $$OUT_PWD/qmldir
copy_qmldir.depends = $$_PRO_FILE_PWD_/qmldir
copy_qmldir.commands = $(COPY_FILE) \"$$replace(copy_qmldir.depends, /, $$QMAKE_DIR_SEP)\" \"$$replace(copy_qmldir.target, /, $$QMAKE_DIR_SEP)\"
QMAKE_EXTRA_TARGETS += copy_qmldir
PRE_TARGETDEPS += $$copy_qmldir.target
}
qmldir.files = qmldir
installPath = $$[QT_INSTALL_QML]/$$replace(uri, \\., /)
qmldir.path = $$installPath
target.path = $$installPath
INSTALLS += target qmldir

60
ScreenPlayWidget/ScreenPlayWidget.pro
View File

@ -1,60 +0,0 @@
QT += quick qml quickcontrols2 core widgets gui
CONFIG += c++17
CONFIG += qtquickcompiler
DEFINES += QT_DEPRECATED_WARNINGS
SOURCES += \
main.cpp \
src/widgetwindow.cpp
HEADERS += \
src/widgetwindow.h
RESOURCES += \
SPWidgetResources.qrc
include(../ScreenPlaySDK/ScreenPlaySDK.pri)
win32 {
CONFIG(debug, debug|release) {
install_it.path = $${OUT_PWD}/debug/
install_it.files += \
$$PWD/../Common/vcpkg/installed/x64-windows/debug/bin/libcrypto-1_1-x64.dll \
$$PWD/../Common/vcpkg/installed/x64-windows/debug/bin/libssl-1_1-x64.dll \
} else {
install_it.path = $${OUT_PWD}/release/
install_it.files += \
$$PWD/../Common/vcpkg/installed/x64-windows/bin/libcrypto-1_1-x64.dll \
$$PWD/../Common/vcpkg/installed/x64-windows/bin/libssl-1_1-x64.dll \
}
}
macx {
QMAKE_LIBDIR += $$OUT_PWD/
}
unix {
install_it.path = $${OUT_PWD}/
CONFIG(debug, debug|release) {
install_it.files += \
$$PWD/../Common/vcpkg/installed/x64-linux/debug/bin/libcrypto-1_1-x64.so \
$$PWD/../Common/vcpkg/installed/x64-linux/debug/bin/libssl-1_1-x64.so \
} else {
install_it.files += \
$$PWD/../Common/vcpkg/installed/x64-linux/bin/libcrypto-1_1-x64.so \
$$PWD/../Common/vcpkg/installed/x64-linux/bin/libssl-1_1-x64.so \
}
}
INSTALLS += install_it

1
stomt-qml

@ -1 +0,0 @@
Subproject commit e7e871512a18d227652a5dd825415e3b59a01de0