mirror of
https://github.com/RPCS3/llvm-mirror.git
synced 2024-11-24 03:33:20 +01:00
29ebc2d39f
Summary: DataLayout keeps the string used for its creation. As a side effect it is no longer needed in the Module. This is "almost" NFC, the string is no longer canonicalized, you can't rely on two "equals" DataLayout having the same string returned by getStringRepresentation(). Get rid of DataLayoutPass: the DataLayout is in the Module The DataLayout is "per-module", let's enforce this by not duplicating it more than necessary. One more step toward non-optionality of the DataLayout in the module. Make DataLayout Non-Optional in the Module Module->getDataLayout() will never returns nullptr anymore. Reviewers: echristo Subscribers: resistor, llvm-commits, jholewinski Differential Revision: http://reviews.llvm.org/D7992 From: Mehdi Amini <mehdi.amini@apple.com> llvm-svn: 231270
56 lines
1.5 KiB
LLVM
56 lines
1.5 KiB
LLVM
; RUN: opt < %s -analyze -delinearize | FileCheck %s
|
|
|
|
; void foo(long n, long m, long o, double A[n][m][o]) {
|
|
;
|
|
; for (long i = 0; i < n; i++)
|
|
; for (long j = 0; j < m; j++)
|
|
; for (long k = 0; k < o; k++)
|
|
; A[i][j][k] = 1.0;
|
|
; }
|
|
|
|
; AddRec: {{{%A,+,(8 * %m * %o)}<%for.i>,+,(8 * %o)}<%for.j>,+,8}<%for.k>
|
|
; CHECK: Base offset: %A
|
|
; CHECK: ArrayDecl[UnknownSize][%m][%o] with elements of 8 bytes.
|
|
; CHECK: ArrayRef[{0,+,1}<nuw><nsw><%for.i>][{0,+,1}<nuw><nsw><%for.j>][{0,+,1}<nuw><nsw><%for.k>]
|
|
|
|
define void @foo(i64 %n, i64 %m, i64 %o, double* %A) {
|
|
entry:
|
|
br label %for.i
|
|
|
|
for.i:
|
|
%i = phi i64 [ 0, %entry ], [ %i.inc, %for.i.inc ]
|
|
br label %for.j
|
|
|
|
for.j:
|
|
%j = phi i64 [ 0, %for.i ], [ %j.inc, %for.j.inc ]
|
|
br label %for.k
|
|
|
|
for.k:
|
|
%k = phi i64 [ 0, %for.j ], [ %k.inc, %for.k.inc ]
|
|
%subscript0 = mul i64 %i, %m
|
|
%subscript1 = add i64 %j, %subscript0
|
|
%subscript2 = mul i64 %subscript1, %o
|
|
%subscript = add i64 %subscript2, %k
|
|
%idx = getelementptr inbounds double, double* %A, i64 %subscript
|
|
store double 1.0, double* %idx
|
|
br label %for.k.inc
|
|
|
|
for.k.inc:
|
|
%k.inc = add nsw i64 %k, 1
|
|
%k.exitcond = icmp eq i64 %k.inc, %o
|
|
br i1 %k.exitcond, label %for.j.inc, label %for.k
|
|
|
|
for.j.inc:
|
|
%j.inc = add nsw i64 %j, 1
|
|
%j.exitcond = icmp eq i64 %j.inc, %m
|
|
br i1 %j.exitcond, label %for.i.inc, label %for.j
|
|
|
|
for.i.inc:
|
|
%i.inc = add nsw i64 %i, 1
|
|
%i.exitcond = icmp eq i64 %i.inc, %n
|
|
br i1 %i.exitcond, label %end, label %for.i
|
|
|
|
end:
|
|
ret void
|
|
}
|