mirror of
https://github.com/RPCS3/llvm-mirror.git
synced 2024-11-23 11:13:28 +01:00
a8bf06418d
Since header files are not compilation units, CMake does not require
you to specify them in the CMakeLists.txt file. As a result, unless a
header file is explicitly added, CMake won't know about it, and when
generating IDE-based projects, CMake won't put the header files into
the IDE project. LLVM currently tries to deal with this in two ways:
1) It looks for all .h files that are in the project directory, and
adds those.
2) llvm_add_library() understands the ADDITIONAL_HEADERS argument,
which allows one to list an arbitrary list of headers.
This patch takes things one step further. It adds the ability for
llvm_add_library() to take an ADDITIONAL_HEADER_DIRS argument, which
will specify a list of folders which CMake will glob for header files.
Furthermore, it will glob not only for .h files, but also for .inc
files.
Included in this CL is an update to one of the existing users of
ADDITIONAL_HEADERS to use this new argument instead, to serve as an
illustration of how this cleans up the CMake.
The big advantage of this new approach is that until now, there was no
way for the IDE projects to locate the header files that are in the
include tree. In other words, if you are in, for example,
lib/DebugInfo/DWARF, the corresponding includes for this project will
be located under include/llvm/DebugInfo/DWARF. Now, in the
CMakeLists.txt for lib/DebugInfo/DWARF, you can simply write:
ADDITIONAL_HEADER_DIRS
../../include/llvm/DebugInfo/DWARF
as an argument to llvm_add_library(), and all header files will get
added to the IDE project.
Differential Revision: http://reviews.llvm.org/D7460
Reviewed By: Chris Bieneman
llvm-svn: 228670
90 lines
2.9 KiB
CMake
90 lines
2.9 KiB
CMake
include(AddFileDependencies)
|
|
include(CMakeParseArguments)
|
|
|
|
function(llvm_replace_compiler_option var old new)
|
|
# Replaces a compiler option or switch `old' in `var' by `new'.
|
|
# If `old' is not in `var', appends `new' to `var'.
|
|
# Example: llvm_replace_compiler_option(CMAKE_CXX_FLAGS_RELEASE "-O3" "-O2")
|
|
# If the option already is on the variable, don't add it:
|
|
if( "${${var}}" MATCHES "(^| )${new}($| )" )
|
|
set(n "")
|
|
else()
|
|
set(n "${new}")
|
|
endif()
|
|
if( "${${var}}" MATCHES "(^| )${old}($| )" )
|
|
string( REGEX REPLACE "(^| )${old}($| )" " ${n} " ${var} "${${var}}" )
|
|
else()
|
|
set( ${var} "${${var}} ${n}" )
|
|
endif()
|
|
set( ${var} "${${var}}" PARENT_SCOPE )
|
|
endfunction(llvm_replace_compiler_option)
|
|
|
|
macro(add_td_sources srcs)
|
|
file(GLOB tds *.td)
|
|
if( tds )
|
|
source_group("TableGen descriptions" FILES ${tds})
|
|
set_source_files_properties(${tds} PROPERTIES HEADER_FILE_ONLY ON)
|
|
list(APPEND ${srcs} ${tds})
|
|
endif()
|
|
endmacro(add_td_sources)
|
|
|
|
function(add_header_files_for_glob hdrs_out glob)
|
|
file(GLOB hds ${glob})
|
|
set(${hdrs_out} ${hds} PARENT_SCOPE)
|
|
endfunction(add_header_files_for_glob)
|
|
|
|
function(find_all_header_files hdrs_out additional_headerdirs)
|
|
add_header_files_for_glob(hds *.h)
|
|
list(APPEND all_headers ${hds})
|
|
|
|
foreach(additional_dir ${additional_headerdirs})
|
|
add_header_files_for_glob(hds "${additional_dir}/*.h")
|
|
list(APPEND all_headers ${hds})
|
|
add_header_files_for_glob(hds "${additional_dir}/*.inc")
|
|
list(APPEND all_headers ${hds})
|
|
endforeach(additional_dir)
|
|
|
|
set( ${hdrs_out} ${all_headers} PARENT_SCOPE )
|
|
endfunction(find_all_header_files)
|
|
|
|
|
|
function(llvm_process_sources OUT_VAR)
|
|
cmake_parse_arguments(ARG "" "" "ADDITIONAL_HEADERS;ADDITIONAL_HEADER_DIRS" ${ARGN})
|
|
set(sources ${ARG_UNPARSED_ARGUMENTS})
|
|
llvm_check_source_file_list( ${sources} )
|
|
if( MSVC_IDE OR XCODE )
|
|
# This adds .td and .h files to the Visual Studio solution:
|
|
add_td_sources(sources)
|
|
find_all_header_files(hdrs "${ARG_ADDITIONAL_HEADER_DIRS}")
|
|
if (hdrs)
|
|
set_source_files_properties(${hdrs} PROPERTIES HEADER_FILE_ONLY ON)
|
|
endif()
|
|
set_source_files_properties(${ARG_ADDITIONAL_HEADERS} PROPERTIES HEADER_FILE_ONLY ON)
|
|
list(APPEND sources ${ARG_ADDITIONAL_HEADERS} ${hdrs})
|
|
endif()
|
|
|
|
set( ${OUT_VAR} ${sources} PARENT_SCOPE )
|
|
endfunction(llvm_process_sources)
|
|
|
|
|
|
function(llvm_check_source_file_list)
|
|
set(listed ${ARGN})
|
|
file(GLOB globbed *.c *.cpp)
|
|
foreach(g ${globbed})
|
|
get_filename_component(fn ${g} NAME)
|
|
|
|
# Don't reject hidden files. Some editors create backups in the
|
|
# same directory as the file.
|
|
if (NOT "${fn}" MATCHES "^\\.")
|
|
list(FIND LLVM_OPTIONAL_SOURCES ${fn} idx)
|
|
if( idx LESS 0 )
|
|
list(FIND listed ${fn} idx)
|
|
if( idx LESS 0 )
|
|
message(SEND_ERROR "Found unknown source file ${g}
|
|
Please update ${CMAKE_CURRENT_LIST_FILE}\n")
|
|
endif()
|
|
endif()
|
|
endif()
|
|
endforeach()
|
|
endfunction(llvm_check_source_file_list)
|