mirror of
https://github.com/RPCS3/llvm-mirror.git
synced 2025-02-01 05:01:59 +01:00
f3a8f80975
Summary: This patch extends the partial inliner to support inlining parts of vararg functions, if the vararg handling is done in the outlined part. It adds a `ForwardVarArgsTo` argument to InlineFunction. If it is non-null, all varargs passed to the inlined function will be added to all calls to `ForwardVarArgsTo`. The partial inliner takes care to only pass `ForwardVarArgsTo` if the varargs handing is done in the outlined function. It checks that vastart is not part of the function to be inlined. `test/Transforms/CodeExtractor/PartialInlineNoInline.ll` (already part of the repo) checks we do not do partial inlining if vastart is used in a basic block that will be inlined. Reviewers: davide, davidxl, grosser Reviewed By: davide, davidxl, grosser Subscribers: gyiu, grosser, eraman, llvm-commits Differential Revision: https://reviews.llvm.org/D39607 llvm-svn: 318028
84 lines
2.6 KiB
LLVM
84 lines
2.6 KiB
LLVM
; RUN: opt < %s -partial-inliner -S -skip-partial-inlining-cost-analysis | FileCheck %s
|
|
; RUN: opt < %s -passes=partial-inliner -S -skip-partial-inlining-cost-analysis | FileCheck %s
|
|
|
|
@stat = external global i32, align 4
|
|
|
|
define i32 @vararg(i32 %count, ...) {
|
|
entry:
|
|
%vargs = alloca i8*, align 8
|
|
%stat1 = load i32, i32* @stat, align 4
|
|
%cmp = icmp slt i32 %stat1, 0
|
|
br i1 %cmp, label %bb2, label %bb1
|
|
|
|
bb1: ; preds = %entry
|
|
%vg1 = add nsw i32 %stat1, 1
|
|
store i32 %vg1, i32* @stat, align 4
|
|
%vargs1 = bitcast i8** %vargs to i8*
|
|
call void @llvm.va_start(i8* %vargs1)
|
|
%va1 = va_arg i8** %vargs, i32
|
|
call void @foo(i32 %count, i32 %va1) #2
|
|
call void @llvm.va_end(i8* %vargs1)
|
|
br label %bb2
|
|
|
|
bb2: ; preds = %bb1, %entry
|
|
%res = phi i32 [ 1, %bb1 ], [ 0, %entry ]
|
|
ret i32 %res
|
|
}
|
|
|
|
declare void @foo(i32, i32)
|
|
declare void @llvm.va_start(i8*)
|
|
declare void @llvm.va_end(i8*)
|
|
|
|
define i32 @caller1(i32 %arg) {
|
|
bb:
|
|
%tmp = tail call i32 (i32, ...) @vararg(i32 %arg)
|
|
ret i32 %tmp
|
|
}
|
|
; CHECK-LABEL: @caller1
|
|
; CHECK: codeRepl.i:
|
|
; CHECK-NEXT: call void (i32, i8**, i32, ...) @vararg.2_bb1(i32 %stat1.i, i8** %vargs.i, i32 %arg)
|
|
|
|
define i32 @caller2(i32 %arg, float %arg2) {
|
|
bb:
|
|
%tmp = tail call i32 (i32, ...) @vararg(i32 %arg, i32 10, float %arg2)
|
|
ret i32 %tmp
|
|
}
|
|
|
|
; CHECK-LABEL: @caller2
|
|
; CHECK: codeRepl.i:
|
|
; CHECK-NEXT: call void (i32, i8**, i32, ...) @vararg.2_bb1(i32 %stat1.i, i8** %vargs.i, i32 %arg, i32 10, float %arg2)
|
|
|
|
; Test case to check that we do not extract a vararg function, if va_end is in
|
|
; a block that is not outlined.
|
|
define i32 @vararg_not_legal(i32 %count, ...) {
|
|
entry:
|
|
%vargs = alloca i8*, align 8
|
|
%vargs0 = bitcast i8** %vargs to i8*
|
|
%stat1 = load i32, i32* @stat, align 4
|
|
%cmp = icmp slt i32 %stat1, 0
|
|
br i1 %cmp, label %bb2, label %bb1
|
|
|
|
bb1: ; preds = %entry
|
|
%vg1 = add nsw i32 %stat1, 1
|
|
store i32 %vg1, i32* @stat, align 4
|
|
%vargs1 = bitcast i8** %vargs to i8*
|
|
call void @llvm.va_start(i8* %vargs1)
|
|
%va1 = va_arg i8** %vargs, i32
|
|
call void @foo(i32 %count, i32 %va1)
|
|
br label %bb2
|
|
|
|
bb2: ; preds = %bb1, %entry
|
|
%res = phi i32 [ 1, %bb1 ], [ 0, %entry ]
|
|
%ptr = phi i8* [ %vargs1, %bb1 ], [ %vargs0, %entry]
|
|
call void @llvm.va_end(i8* %ptr)
|
|
ret i32 %res
|
|
}
|
|
|
|
; CHECK-LABEL: @caller3
|
|
; CHECK: tail call i32 (i32, ...) @vararg_not_legal(i32 %arg, i32 %arg)
|
|
define i32 @caller3(i32 %arg) {
|
|
bb:
|
|
%res = tail call i32 (i32, ...) @vararg_not_legal(i32 %arg, i32 %arg)
|
|
ret i32 %res
|
|
}
|