mirror of
https://github.com/RPCS3/llvm-mirror.git
synced 2024-11-23 11:13:28 +01:00
2a670b2329
The new fptrunc and fpext intrinsics are constrained versions of the regular fptrunc and fpext instructions. Reviewed by: Andrew Kaylor, Craig Topper, Cameron McInally, Conner Abbot Approved by: Craig Topper Differential Revision: https://reviews.llvm.org/D55897 llvm-svn: 360581
289 lines
12 KiB
LLVM
289 lines
12 KiB
LLVM
; RUN: opt -O3 -S < %s | FileCheck %s
|
|
|
|
; Test to verify that constants aren't folded when the rounding mode is unknown.
|
|
; CHECK-LABEL: @f1
|
|
; CHECK: call double @llvm.experimental.constrained.fdiv.f64
|
|
define double @f1() {
|
|
entry:
|
|
%div = call double @llvm.experimental.constrained.fdiv.f64(
|
|
double 1.000000e+00,
|
|
double 1.000000e+01,
|
|
metadata !"round.dynamic",
|
|
metadata !"fpexcept.strict")
|
|
ret double %div
|
|
}
|
|
|
|
; Verify that 'a - 0' isn't simplified to 'a' when the rounding mode is unknown.
|
|
;
|
|
; double f2(double a) {
|
|
; // Because the result of '0 - 0' is negative zero if rounding mode is
|
|
; // downward, this shouldn't be simplified.
|
|
; return a - 0.0;
|
|
; }
|
|
;
|
|
; CHECK-LABEL: @f2
|
|
; CHECK: call double @llvm.experimental.constrained.fsub.f64
|
|
define double @f2(double %a) {
|
|
entry:
|
|
%div = call double @llvm.experimental.constrained.fsub.f64(
|
|
double %a, double 0.000000e+00,
|
|
metadata !"round.dynamic",
|
|
metadata !"fpexcept.strict")
|
|
ret double %div
|
|
}
|
|
|
|
; Verify that '-((-a)*b)' isn't simplified to 'a*b' when the rounding mode is
|
|
; unknown.
|
|
;
|
|
; double f3(double a, double b) {
|
|
; // Because the intermediate value involved in this calculation may require
|
|
; // rounding, this shouldn't be simplified.
|
|
; return -((-a)*b);
|
|
; }
|
|
;
|
|
; CHECK-LABEL: @f3
|
|
; CHECK: call double @llvm.experimental.constrained.fsub.f64
|
|
; CHECK: call double @llvm.experimental.constrained.fmul.f64
|
|
; CHECK: call double @llvm.experimental.constrained.fsub.f64
|
|
define double @f3(double %a, double %b) {
|
|
entry:
|
|
%sub = call double @llvm.experimental.constrained.fsub.f64(
|
|
double -0.000000e+00, double %a,
|
|
metadata !"round.dynamic",
|
|
metadata !"fpexcept.strict")
|
|
%mul = call double @llvm.experimental.constrained.fmul.f64(
|
|
double %sub, double %b,
|
|
metadata !"round.dynamic",
|
|
metadata !"fpexcept.strict")
|
|
%ret = call double @llvm.experimental.constrained.fsub.f64(
|
|
double -0.000000e+00,
|
|
double %mul,
|
|
metadata !"round.dynamic",
|
|
metadata !"fpexcept.strict")
|
|
ret double %ret
|
|
}
|
|
|
|
; Verify that FP operations are not performed speculatively when FP exceptions
|
|
; are not being ignored.
|
|
;
|
|
; double f4(int n, double a) {
|
|
; // Because a + 1 may overflow, this should not be simplified.
|
|
; if (n > 0)
|
|
; return a + 1.0;
|
|
; return a;
|
|
; }
|
|
;
|
|
;
|
|
; CHECK-LABEL: @f4
|
|
; CHECK-NOT: select
|
|
; CHECK: br i1 %cmp
|
|
define double @f4(i32 %n, double %a) {
|
|
entry:
|
|
%cmp = icmp sgt i32 %n, 0
|
|
br i1 %cmp, label %if.then, label %if.end
|
|
|
|
if.then:
|
|
%add = call double @llvm.experimental.constrained.fadd.f64(
|
|
double 1.000000e+00, double %a,
|
|
metadata !"round.dynamic",
|
|
metadata !"fpexcept.strict")
|
|
br label %if.end
|
|
|
|
if.end:
|
|
%a.0 = phi double [%add, %if.then], [ %a, %entry ]
|
|
ret double %a.0
|
|
}
|
|
|
|
; Verify that sqrt(42.0) isn't simplified when the rounding mode is unknown.
|
|
; CHECK-LABEL: f5
|
|
; CHECK: call double @llvm.experimental.constrained.sqrt
|
|
define double @f5() {
|
|
entry:
|
|
%result = call double @llvm.experimental.constrained.sqrt.f64(double 42.0,
|
|
metadata !"round.dynamic",
|
|
metadata !"fpexcept.strict")
|
|
ret double %result
|
|
}
|
|
|
|
; Verify that pow(42.1, 3.0) isn't simplified when the rounding mode is unknown.
|
|
; CHECK-LABEL: f6
|
|
; CHECK: call double @llvm.experimental.constrained.pow
|
|
define double @f6() {
|
|
entry:
|
|
%result = call double @llvm.experimental.constrained.pow.f64(double 42.1,
|
|
double 3.0,
|
|
metadata !"round.dynamic",
|
|
metadata !"fpexcept.strict")
|
|
ret double %result
|
|
}
|
|
|
|
; Verify that powi(42.1, 3) isn't simplified when the rounding mode is unknown.
|
|
; CHECK-LABEL: f7
|
|
; CHECK: call double @llvm.experimental.constrained.powi
|
|
define double @f7() {
|
|
entry:
|
|
%result = call double @llvm.experimental.constrained.powi.f64(double 42.1,
|
|
i32 3,
|
|
metadata !"round.dynamic",
|
|
metadata !"fpexcept.strict")
|
|
ret double %result
|
|
}
|
|
|
|
; Verify that sin(42.0) isn't simplified when the rounding mode is unknown.
|
|
; CHECK-LABEL: f8
|
|
; CHECK: call double @llvm.experimental.constrained.sin
|
|
define double @f8() {
|
|
entry:
|
|
%result = call double @llvm.experimental.constrained.sin.f64(double 42.0,
|
|
metadata !"round.dynamic",
|
|
metadata !"fpexcept.strict")
|
|
ret double %result
|
|
}
|
|
|
|
; Verify that cos(42.0) isn't simplified when the rounding mode is unknown.
|
|
; CHECK-LABEL: f9
|
|
; CHECK: call double @llvm.experimental.constrained.cos
|
|
define double @f9() {
|
|
entry:
|
|
%result = call double @llvm.experimental.constrained.cos.f64(double 42.0,
|
|
metadata !"round.dynamic",
|
|
metadata !"fpexcept.strict")
|
|
ret double %result
|
|
}
|
|
|
|
; Verify that exp(42.0) isn't simplified when the rounding mode is unknown.
|
|
; CHECK-LABEL: f10
|
|
; CHECK: call double @llvm.experimental.constrained.exp
|
|
define double @f10() {
|
|
entry:
|
|
%result = call double @llvm.experimental.constrained.exp.f64(double 42.0,
|
|
metadata !"round.dynamic",
|
|
metadata !"fpexcept.strict")
|
|
ret double %result
|
|
}
|
|
|
|
; Verify that exp2(42.1) isn't simplified when the rounding mode is unknown.
|
|
; CHECK-LABEL: f11
|
|
; CHECK: call double @llvm.experimental.constrained.exp2
|
|
define double @f11() {
|
|
entry:
|
|
%result = call double @llvm.experimental.constrained.exp2.f64(double 42.1,
|
|
metadata !"round.dynamic",
|
|
metadata !"fpexcept.strict")
|
|
ret double %result
|
|
}
|
|
|
|
; Verify that log(42.0) isn't simplified when the rounding mode is unknown.
|
|
; CHECK-LABEL: f12
|
|
; CHECK: call double @llvm.experimental.constrained.log
|
|
define double @f12() {
|
|
entry:
|
|
%result = call double @llvm.experimental.constrained.log.f64(double 42.0,
|
|
metadata !"round.dynamic",
|
|
metadata !"fpexcept.strict")
|
|
ret double %result
|
|
}
|
|
|
|
; Verify that log10(42.0) isn't simplified when the rounding mode is unknown.
|
|
; CHECK-LABEL: f13
|
|
; CHECK: call double @llvm.experimental.constrained.log10
|
|
define double @f13() {
|
|
entry:
|
|
%result = call double @llvm.experimental.constrained.log10.f64(double 42.0,
|
|
metadata !"round.dynamic",
|
|
metadata !"fpexcept.strict")
|
|
ret double %result
|
|
}
|
|
|
|
; Verify that log2(42.0) isn't simplified when the rounding mode is unknown.
|
|
; CHECK-LABEL: f14
|
|
; CHECK: call double @llvm.experimental.constrained.log2
|
|
define double @f14() {
|
|
entry:
|
|
%result = call double @llvm.experimental.constrained.log2.f64(double 42.0,
|
|
metadata !"round.dynamic",
|
|
metadata !"fpexcept.strict")
|
|
ret double %result
|
|
}
|
|
|
|
; Verify that rint(42.1) isn't simplified when the rounding mode is unknown.
|
|
; CHECK-LABEL: f15
|
|
; CHECK: call double @llvm.experimental.constrained.rint
|
|
define double @f15() {
|
|
entry:
|
|
%result = call double @llvm.experimental.constrained.rint.f64(double 42.1,
|
|
metadata !"round.dynamic",
|
|
metadata !"fpexcept.strict")
|
|
ret double %result
|
|
}
|
|
|
|
; Verify that nearbyint(42.1) isn't simplified when the rounding mode is
|
|
; unknown.
|
|
; CHECK-LABEL: f16
|
|
; CHECK: call double @llvm.experimental.constrained.nearbyint
|
|
define double @f16() {
|
|
entry:
|
|
%result = call double @llvm.experimental.constrained.nearbyint.f64(
|
|
double 42.1,
|
|
metadata !"round.dynamic",
|
|
metadata !"fpexcept.strict")
|
|
ret double %result
|
|
}
|
|
|
|
; Verify that fma(42.1) isn't simplified when the rounding mode is
|
|
; unknown.
|
|
; CHECK-LABEL: f17
|
|
; CHECK: call double @llvm.experimental.constrained.fma
|
|
define double @f17() {
|
|
entry:
|
|
%result = call double @llvm.experimental.constrained.fma.f64(double 42.1, double 42.1, double 42.1,
|
|
metadata !"round.dynamic",
|
|
metadata !"fpexcept.strict")
|
|
ret double %result
|
|
}
|
|
|
|
; Verify that fptrunc(42.1) isn't simplified when the rounding mode is
|
|
; unknown.
|
|
; CHECK-LABEL: f20
|
|
; CHECK: call float @llvm.experimental.constrained.fptrunc
|
|
define float @f20() {
|
|
entry:
|
|
%result = call float @llvm.experimental.constrained.fptrunc.f32.f64(
|
|
double 42.1,
|
|
metadata !"round.dynamic",
|
|
metadata !"fpexcept.strict")
|
|
ret float %result
|
|
}
|
|
|
|
; Verify that fpext(42.1) isn't simplified when the rounding mode is
|
|
; unknown.
|
|
; CHECK-LABEL: f21
|
|
; CHECK: call double @llvm.experimental.constrained.fpext
|
|
define double @f21() {
|
|
entry:
|
|
%result = call double @llvm.experimental.constrained.fpext.f64.f32(float 42.0,
|
|
metadata !"fpexcept.strict")
|
|
ret double %result
|
|
}
|
|
|
|
@llvm.fp.env = thread_local global i8 zeroinitializer, section "llvm.metadata"
|
|
declare double @llvm.experimental.constrained.fdiv.f64(double, double, metadata, metadata)
|
|
declare double @llvm.experimental.constrained.fmul.f64(double, double, metadata, metadata)
|
|
declare double @llvm.experimental.constrained.fadd.f64(double, double, metadata, metadata)
|
|
declare double @llvm.experimental.constrained.fsub.f64(double, double, metadata, metadata)
|
|
declare double @llvm.experimental.constrained.sqrt.f64(double, metadata, metadata)
|
|
declare double @llvm.experimental.constrained.pow.f64(double, double, metadata, metadata)
|
|
declare double @llvm.experimental.constrained.powi.f64(double, i32, metadata, metadata)
|
|
declare double @llvm.experimental.constrained.sin.f64(double, metadata, metadata)
|
|
declare double @llvm.experimental.constrained.cos.f64(double, metadata, metadata)
|
|
declare double @llvm.experimental.constrained.exp.f64(double, metadata, metadata)
|
|
declare double @llvm.experimental.constrained.exp2.f64(double, metadata, metadata)
|
|
declare double @llvm.experimental.constrained.log.f64(double, metadata, metadata)
|
|
declare double @llvm.experimental.constrained.log10.f64(double, metadata, metadata)
|
|
declare double @llvm.experimental.constrained.log2.f64(double, metadata, metadata)
|
|
declare double @llvm.experimental.constrained.rint.f64(double, metadata, metadata)
|
|
declare double @llvm.experimental.constrained.nearbyint.f64(double, metadata, metadata)
|
|
declare double @llvm.experimental.constrained.fma.f64(double, double, double, metadata, metadata)
|
|
declare float @llvm.experimental.constrained.fptrunc.f32.f64(double, metadata, metadata)
|
|
declare double @llvm.experimental.constrained.fpext.f64.f32(float, metadata)
|