mirror of
https://github.com/RPCS3/llvm-mirror.git
synced 2024-10-24 21:42:54 +02:00
5b68eeb27b
This change is mostly motivated by exposing information about the original query instruction to the actual scanning work in getPointerDependencyFrom when used by GVN PRE. In a follow up change, I will use this to be more precise with regards to the semantics of volatile instructions encountered in the scan of a basic block. Worth noting, is that this change (despite appearing quite simple) is not semantically preserving. By providing more information to the helper routine, we allow some optimizations to kick in that weren't previously able to (when called from this code path.) In particular, we see that treatment of !invariant.load becomes more precise. In theory, we might see a difference with an ordered/atomic instruction as well, but I'm having a hard time actually finding a test case which shows that. Test wise, I've included new tests for !invariant.load which illustrate this difference. I've also included some updated TBAA tests which highlight that this change isn't needed for that optimization to kick in - it's handled inside alias analysis itself. Eventually, it would be nice to factor the !invariant.load handling inside alias analysis as well. Differential Revision: http://reviews.llvm.org/D6895 llvm-svn: 227110
70 lines
1.6 KiB
LLVM
70 lines
1.6 KiB
LLVM
; Test if the !invariant.load metadata is maintained by GVN.
|
|
; RUN: opt -basicaa -gvn -S < %s | FileCheck %s
|
|
|
|
define i32 @test1(i32* nocapture %p, i8* nocapture %q) {
|
|
; CHECK-LABEL: test1
|
|
; CHECK: %x = load i32* %p, align 4, !invariant.load !0
|
|
; CHECK-NOT: %y = load
|
|
entry:
|
|
%x = load i32* %p, align 4, !invariant.load !0
|
|
%conv = trunc i32 %x to i8
|
|
store i8 %conv, i8* %q, align 1
|
|
%y = load i32* %p, align 4, !invariant.load !0
|
|
%add = add i32 %y, 1
|
|
ret i32 %add
|
|
}
|
|
|
|
define i32 @test2(i32* nocapture %p, i8* nocapture %q) {
|
|
; CHECK-LABEL: test2
|
|
; CHECK-NOT: !invariant.load
|
|
; CHECK-NOT: %y = load
|
|
entry:
|
|
%x = load i32* %p, align 4
|
|
%conv = trunc i32 %x to i8
|
|
store i8 %conv, i8* %q, align 1
|
|
%y = load i32* %p, align 4, !invariant.load !0
|
|
%add = add i32 %y, 1
|
|
ret i32 %add
|
|
}
|
|
|
|
; With the invariant.load metadata, what would otherwise
|
|
; be a case for PRE becomes a full redundancy.
|
|
define i32 @test3(i1 %cnd, i32* %p, i32* %q) {
|
|
; CHECK-LABEL: test3
|
|
; CHECK-NOT: load
|
|
entry:
|
|
%v1 = load i32* %p
|
|
br i1 %cnd, label %bb1, label %bb2
|
|
|
|
bb1:
|
|
store i32 5, i32* %q
|
|
br label %bb2
|
|
|
|
bb2:
|
|
%v2 = load i32* %p, !invariant.load !0
|
|
%res = sub i32 %v1, %v2
|
|
ret i32 %res
|
|
}
|
|
|
|
; This test is here to document a case which doesn't optimize
|
|
; as well as it could.
|
|
define i32 @test4(i1 %cnd, i32* %p, i32* %q) {
|
|
; CHECK-LABEL: test4
|
|
; %v2 is redundant, but GVN currently doesn't catch that
|
|
entry:
|
|
%v1 = load i32* %p, !invariant.load !0
|
|
br i1 %cnd, label %bb1, label %bb2
|
|
|
|
bb1:
|
|
store i32 5, i32* %q
|
|
br label %bb2
|
|
|
|
bb2:
|
|
%v2 = load i32* %p
|
|
%res = sub i32 %v1, %v2
|
|
ret i32 %res
|
|
}
|
|
|
|
!0 = !{ }
|
|
|