mirror of
https://github.com/RPCS3/llvm-mirror.git
synced 2025-02-01 05:01:59 +01:00
f4af38fa5f
Summary: This is largely NFC*, in preparation for utilizing ProfileSummaryInfo and BranchFrequencyInfo analyses. In this patch I am only doing the splitting for the New PM, but I can do the same for the legacy PM as a follow-on if this looks good. *Not NFC since for partial unrolling we lose the updates done to the loop traversal (adding new sibling and child loops) - according to Chandler this is not very useful for partial unrolling, but it also means that the debugging flag -unroll-revisit-child-loops no longer works for partial unrolling. Reviewers: chandlerc Subscribers: mehdi_amini, mzolotukhin, eraman, llvm-commits Differential Revision: https://reviews.llvm.org/D36157 llvm-svn: 309886
157 lines
5.2 KiB
LLVM
157 lines
5.2 KiB
LLVM
; This test checks that nested loops are revisited in various scenarios when
|
|
; unrolling. Note that if we ever start doing outer loop peeling a test case
|
|
; for that should be added here that will look essentially like a hybrid of the
|
|
; current two cases.
|
|
;
|
|
; RUN: opt < %s -disable-output -debug-pass-manager 2>&1 \
|
|
; RUN: -passes='require<opt-remark-emit>,loop(unroll-full)' \
|
|
; RUN: | FileCheck %s
|
|
;
|
|
; Also run in a special mode that visits children.
|
|
; RUN: opt < %s -disable-output -debug-pass-manager -unroll-revisit-child-loops 2>&1 \
|
|
; RUN: -passes='require<opt-remark-emit>,loop(unroll-full)' \
|
|
; RUN: | FileCheck %s --check-prefixes=CHECK,CHECK-CHILDREN
|
|
|
|
; Basic test is fully unrolled and we revisit the post-unroll new sibling
|
|
; loops, including the ones that used to be child loops.
|
|
define void @full_unroll(i1* %ptr) {
|
|
; CHECK-LABEL: FunctionToLoopPassAdaptor{{.*}} on full_unroll
|
|
; CHECK-NOT: LoopFullUnrollPass
|
|
|
|
entry:
|
|
br label %l0
|
|
|
|
l0:
|
|
%cond.0 = load volatile i1, i1* %ptr
|
|
br i1 %cond.0, label %l0.0.ph, label %exit
|
|
|
|
l0.0.ph:
|
|
br label %l0.0
|
|
|
|
l0.0:
|
|
%iv = phi i32 [ %iv.next, %l0.0.latch ], [ 0, %l0.0.ph ]
|
|
%iv.next = add i32 %iv, 1
|
|
br label %l0.0.0.ph
|
|
|
|
l0.0.0.ph:
|
|
br label %l0.0.0
|
|
|
|
l0.0.0:
|
|
%cond.0.0.0 = load volatile i1, i1* %ptr
|
|
br i1 %cond.0.0.0, label %l0.0.0, label %l0.0.1.ph
|
|
; CHECK: LoopFullUnrollPass on Loop at depth 3 containing: %l0.0.0<header>
|
|
; CHECK-NOT: LoopFullUnrollPass
|
|
|
|
l0.0.1.ph:
|
|
br label %l0.0.1
|
|
|
|
l0.0.1:
|
|
%cond.0.0.1 = load volatile i1, i1* %ptr
|
|
br i1 %cond.0.0.1, label %l0.0.1, label %l0.0.latch
|
|
; CHECK: LoopFullUnrollPass on Loop at depth 3 containing: %l0.0.1<header>
|
|
; CHECK-NOT: LoopFullUnrollPass
|
|
|
|
l0.0.latch:
|
|
%cmp = icmp slt i32 %iv.next, 2
|
|
br i1 %cmp, label %l0.0, label %l0.latch
|
|
; CHECK: LoopFullUnrollPass on Loop at depth 2 containing: %l0.0
|
|
; CHECK-NOT: LoopFullUnrollPass
|
|
;
|
|
; Unrolling occurs, so we visit what were the inner loops twice over. First we
|
|
; visit their clones, and then we visit the original loops re-parented.
|
|
; CHECK: LoopFullUnrollPass on Loop at depth 2 containing: %l0.0.1.1<header>
|
|
; CHECK-NOT: LoopFullUnrollPass
|
|
; CHECK: LoopFullUnrollPass on Loop at depth 2 containing: %l0.0.0.1<header>
|
|
; CHECK-NOT: LoopFullUnrollPass
|
|
; CHECK: LoopFullUnrollPass on Loop at depth 2 containing: %l0.0.1<header>
|
|
; CHECK-NOT: LoopFullUnrollPass
|
|
; CHECK: LoopFullUnrollPass on Loop at depth 2 containing: %l0.0.0<header>
|
|
; CHECK-NOT: LoopFullUnrollPass
|
|
|
|
l0.latch:
|
|
br label %l0
|
|
; CHECK: LoopFullUnrollPass on Loop at depth 1 containing: %l0<header>
|
|
; CHECK-NOT: LoopFullUnrollPass
|
|
|
|
exit:
|
|
ret void
|
|
}
|
|
|
|
; Now we test forced runtime partial unrolling with metadata. Here we end up
|
|
; duplicating child loops without changing their structure and so they aren't by
|
|
; default visited, but will be visited with a special parameter.
|
|
define void @partial_unroll(i32 %count, i1* %ptr) {
|
|
; CHECK-LABEL: FunctionToLoopPassAdaptor{{.*}} on partial_unroll
|
|
; CHECK-NOT: LoopFullUnrollPass
|
|
|
|
entry:
|
|
br label %l0
|
|
|
|
l0:
|
|
%cond.0 = load volatile i1, i1* %ptr
|
|
br i1 %cond.0, label %l0.0.ph, label %exit
|
|
|
|
l0.0.ph:
|
|
br label %l0.0
|
|
|
|
l0.0:
|
|
%iv = phi i32 [ %iv.next, %l0.0.latch ], [ 0, %l0.0.ph ]
|
|
%iv.next = add i32 %iv, 1
|
|
br label %l0.0.0.ph
|
|
|
|
l0.0.0.ph:
|
|
br label %l0.0.0
|
|
|
|
l0.0.0:
|
|
%cond.0.0.0 = load volatile i1, i1* %ptr
|
|
br i1 %cond.0.0.0, label %l0.0.0, label %l0.0.1.ph
|
|
; CHECK: LoopFullUnrollPass on Loop at depth 3 containing: %l0.0.0<header>
|
|
; CHECK-NOT: LoopFullUnrollPass
|
|
|
|
l0.0.1.ph:
|
|
br label %l0.0.1
|
|
|
|
l0.0.1:
|
|
%cond.0.0.1 = load volatile i1, i1* %ptr
|
|
br i1 %cond.0.0.1, label %l0.0.1, label %l0.0.latch
|
|
; CHECK: LoopFullUnrollPass on Loop at depth 3 containing: %l0.0.1<header>
|
|
; CHECK-NOT: LoopFullUnrollPass
|
|
|
|
l0.0.latch:
|
|
%cmp = icmp slt i32 %iv.next, %count
|
|
br i1 %cmp, label %l0.0, label %l0.latch, !llvm.loop !1
|
|
; CHECK: LoopFullUnrollPass on Loop at depth 2 containing: %l0.0
|
|
; CHECK-NOT: LoopFullUnrollPass
|
|
;
|
|
; Partial unrolling occurs which introduces both new child loops and new sibling
|
|
; loops. We only visit the child loops in a special mode, not by default.
|
|
; CHECK-CHILDREN: LoopFullUnrollPass on Loop at depth 3 containing: %l0.0.0<header>
|
|
; CHECK-CHILDREN-NOT: LoopFullUnrollPass
|
|
; CHECK-CHILDREN: LoopFullUnrollPass on Loop at depth 3 containing: %l0.0.1<header>
|
|
; CHECK-CHILDREN-NOT: LoopFullUnrollPass
|
|
; CHECK-CHILDREN: LoopFullUnrollPass on Loop at depth 3 containing: %l0.0.0.1<header>
|
|
; CHECK-CHILDREN-NOT: LoopFullUnrollPass
|
|
; CHECK-CHILDREN: LoopFullUnrollPass on Loop at depth 3 containing: %l0.0.1.1<header>
|
|
; CHECK-CHILDREN-NOT: LoopFullUnrollPass
|
|
;
|
|
; When we revisit children, we also revisit the current loop.
|
|
; CHECK-CHILDREN: LoopFullUnrollPass on Loop at depth 2 containing: %l0.0<header>
|
|
; CHECK-CHILDREN-NOT: LoopFullUnrollPass
|
|
;
|
|
; Revisit the children of the outer loop that are part of the epilogue.
|
|
;
|
|
; CHECK: LoopFullUnrollPass on Loop at depth 2 containing: %l0.0.0.epil<header>
|
|
; CHECK-NOT: LoopFullUnrollPass
|
|
; CHECK: LoopFullUnrollPass on Loop at depth 2 containing: %l0.0.1.epil<header>
|
|
; CHECK-NOT: LoopFullUnrollPass
|
|
l0.latch:
|
|
br label %l0
|
|
; CHECK: LoopFullUnrollPass on Loop at depth 1 containing: %l0<header>
|
|
; CHECK-NOT: LoopFullUnrollPass
|
|
|
|
exit:
|
|
ret void
|
|
}
|
|
!1 = !{!1, !2}
|
|
!2 = !{!"llvm.loop.unroll.count", i32 2}
|