mirror of
https://github.com/RPCS3/llvm-mirror.git
synced 2024-10-25 05:52:53 +02:00
de9991d3c2
Summary: This makes attribute accessors on `CallInst` and `InvokeInst` do the (conservatively) right thing. This essentially involves, in some cases, *not* falling back querying the attributes on the called `llvm::Function` when operand bundles are present. Attributes locally present on the `CallInst` or `InvokeInst` will still override operand bundle semantics. The LangRef has been amended to reflect this. Note: this change does not do anything prevent `-function-attrs` from inferring `CallSite` local attributes after inspecting the called function -- that will be done as a separate change. I've used `-adce` and `-early-cse` to test these changes. There is nothing special about these passes (and they did not require any changes) except that they seemed be the easiest way to write the tests. This change does not add deal with `argmemonly`. That's a later change because alias analysis requires a related fix before `argmemonly` can be tested. Reviewers: reames, chandlerc Subscribers: llvm-commits Differential Revision: http://reviews.llvm.org/D13961 llvm-svn: 250973
72 lines
1.7 KiB
LLVM
72 lines
1.7 KiB
LLVM
; RUN: opt -S -early-cse < %s | FileCheck %s
|
|
|
|
; While it is normally okay to do memory optimizations over calls to
|
|
; @readonly_function and @readnone_function, we cannot do that if
|
|
; they're carrying operand bundles since the presence of unknown
|
|
; operand bundles implies arbitrary memory effects.
|
|
|
|
declare void @readonly_function() readonly nounwind
|
|
declare void @readnone_function() readnone nounwind
|
|
|
|
define i32 @test0(i32* %x) {
|
|
; CHECK-LABEL: @test0(
|
|
entry:
|
|
store i32 100, i32* %x
|
|
; CHECK: store i32 100, i32* %x
|
|
call void @readonly_function() [ "tag"() ]
|
|
; CHECK: call void @readonly_function()
|
|
|
|
%v = load i32, i32* %x
|
|
; CHECK: %v = load i32, i32* %x
|
|
; CHECK: ret i32 %v
|
|
ret i32 %v
|
|
}
|
|
|
|
define i32 @test1(i32* %x) {
|
|
; CHECK: @test1(
|
|
entry:
|
|
store i32 100, i32* %x
|
|
; CHECK: store i32 100, i32* %x
|
|
call void @readonly_function() readonly [ "tag"() ]
|
|
; CHECK-NOT: call void @readonly_function
|
|
%v = load i32, i32* %x
|
|
ret i32 %v
|
|
; CHECK: ret i32 100
|
|
}
|
|
|
|
define i32 @test3(i32* %x) {
|
|
; CHECK-LABEL: @test3(
|
|
entry:
|
|
store i32 100, i32* %x
|
|
; CHECK: store i32 100, i32* %x
|
|
call void @readonly_function()
|
|
; CHECK-NOT: call void @readonly_function
|
|
%v = load i32, i32* %x
|
|
ret i32 %v
|
|
; CHECK: ret i32 100
|
|
}
|
|
|
|
define void @test4(i32* %x) {
|
|
; CHECK-LABEL: @test4(
|
|
entry:
|
|
store i32 100, i32* %x
|
|
; CHECK: store i32 100, i32* %x
|
|
call void @readnone_function() [ "tag"() ]
|
|
; CHECK: call void @readnone_function
|
|
store i32 200, i32* %x
|
|
; CHECK: store i32 200, i32* %x
|
|
ret void
|
|
}
|
|
|
|
define void @test5(i32* %x) {
|
|
; CHECK-LABEL: @test5(
|
|
entry:
|
|
store i32 100, i32* %x
|
|
; CHECK-NOT: store i32 100, i32* %x
|
|
; CHECK-NOT: call void @readnone_function
|
|
call void @readnone_function() readnone [ "tag"() ]
|
|
store i32 200, i32* %x
|
|
; CHECK: store i32 200, i32* %x
|
|
ret void
|
|
}
|