mirror of
https://github.com/RPCS3/llvm-mirror.git
synced 2024-11-25 20:23:11 +01:00
95a256f279
I've made a range of improvements to the Emacs mode for LLVM IR. Most importantly, it changes llvm-mode to inherit from prog-mode. This means llvm-mode will be treated as a normal programming mode in Emacs, so many Emacs features will just work. prog-mode is new to Emacs 24, so I've added an alias to ensure compatibility with Emacs 23 too. I've changed the mode definition to use define-derived-mode. This saves us needing to set up local variables ourselves, and saves us needing to define llvm-mode-map, llvm-mode-abbrev-table, llvm-mode-map. I've removed the keybindings to tab-to-tab-stop, center-line and center-paragraph. This shouldn't be llvm-mode's responsibility, and the code didn't actually work anyway (since `(not llvm-mode-map)` always evaluated to `t`, the keybindings were never executed). I've simplified the syntax-table definition, it's equivalent (e.g. `"` is treated as string delimiter by default in Emacs). I've added `.` as a symbol constituent, so functions like `llvm.memset.p0i8.i32` are recognised as a single symbol. I've also changed `%` to be a symbol constituent, so users can move between words or symbols at their choice, rather than conflating the two. I've fixed regexp for types, which incorrect used `symbol` instead of `symbols` as an argument to `regexp-opt`. This was causing incorrect highlighting on lines like `call void @foovoid`. I've removed string and comment highlighting from `llvm-font-lock-keywords`. This is already handled by the syntax-table. Finally, I've removed the reference to jasmin. That project is long abandoned and the link 404s. For reference, I've found an old copy of the project here: https://github.com/stevej/emacs/blob/master/vendor/jasmin/jasmin.el Patch by Wilfred Hughes! llvm-svn: 247281
86 lines
3.6 KiB
EmacsLisp
86 lines
3.6 KiB
EmacsLisp
;;; llvm-mode.el --- Major mode for the LLVM assembler language.
|
|
|
|
;; Maintainer: The LLVM team, http://llvm.org/
|
|
|
|
;;; Commentary:
|
|
|
|
;; Major mode for editing LLVM IR files.
|
|
|
|
;;; Code:
|
|
|
|
(defvar llvm-mode-syntax-table
|
|
(let ((table (make-syntax-table)))
|
|
(modify-syntax-entry ?% "_" table)
|
|
(modify-syntax-entry ?. "_" table)
|
|
(modify-syntax-entry ?\; "< " table)
|
|
(modify-syntax-entry ?\n "> " table)
|
|
table)
|
|
"Syntax table used while in LLVM mode.")
|
|
|
|
(defvar llvm-font-lock-keywords
|
|
(list
|
|
;; Variables
|
|
'("%[-a-zA-Z$\._][-a-zA-Z$\._0-9]*" . font-lock-variable-name-face)
|
|
;; Labels
|
|
'("[-a-zA-Z$\._0-9]+:" . font-lock-variable-name-face)
|
|
;; Unnamed variable slots
|
|
'("%[-]?[0-9]+" . font-lock-variable-name-face)
|
|
;; Types
|
|
`(,(regexp-opt '("void" "i1" "i8" "i16" "i32" "i64" "i128" "float" "double" "type" "label" "opaque") 'symbols) . font-lock-type-face)
|
|
;; Integer literals
|
|
'("\\b[-]?[0-9]+\\b" . font-lock-preprocessor-face)
|
|
;; Floating point constants
|
|
'("\\b[-+]?[0-9]+\.[0-9]*\([eE][-+]?[0-9]+\)?\\b" . font-lock-preprocessor-face)
|
|
;; Hex constants
|
|
'("\\b0x[0-9A-Fa-f]+\\b" . font-lock-preprocessor-face)
|
|
;; Keywords
|
|
`(,(regexp-opt '("begin" "end" "true" "false" "zeroinitializer" "declare"
|
|
"define" "global" "constant" "const" "internal" "linkonce" "linkonce_odr"
|
|
"weak" "weak_odr" "appending" "uninitialized" "implementation" "..."
|
|
"null" "undef" "to" "except" "not" "target" "endian" "little" "big"
|
|
"pointersize" "volatile" "fastcc" "coldcc" "cc" "personality") 'symbols) . font-lock-keyword-face)
|
|
;; Arithmetic and Logical Operators
|
|
`(,(regexp-opt '("add" "sub" "mul" "sdiv" "udiv" "urem" "srem" "and" "or" "xor"
|
|
"setne" "seteq" "setlt" "setgt" "setle" "setge") 'symbols) . font-lock-keyword-face)
|
|
;; Floating-point operators
|
|
`(,(regexp-opt '("fadd" "fsub" "fmul" "fdiv" "frem") 'symbols) . font-lock-keyword-face)
|
|
;; Special instructions
|
|
`(,(regexp-opt '("phi" "tail" "call" "select" "to" "shl" "lshr" "ashr" "fcmp" "icmp" "va_arg" "landingpad") 'symbols) . font-lock-keyword-face)
|
|
;; Control instructions
|
|
`(,(regexp-opt '("ret" "br" "switch" "invoke" "resume" "unwind" "unreachable" "indirectbr") 'symbols) . font-lock-keyword-face)
|
|
;; Memory operators
|
|
`(,(regexp-opt '("malloc" "alloca" "free" "load" "store" "getelementptr" "fence" "cmpxchg" "atomicrmw") 'symbols) . font-lock-keyword-face)
|
|
;; Casts
|
|
`(,(regexp-opt '("bitcast" "inttoptr" "ptrtoint" "trunc" "zext" "sext" "fptrunc" "fpext" "fptoui" "fptosi" "uitofp" "sitofp" "addrspacecast") 'symbols) . font-lock-keyword-face)
|
|
;; Vector ops
|
|
`(,(regexp-opt '("extractelement" "insertelement" "shufflevector") 'symbols) . font-lock-keyword-face)
|
|
;; Aggregate ops
|
|
`(,(regexp-opt '("extractvalue" "insertvalue") 'symbols) . font-lock-keyword-face)
|
|
;; Metadata types
|
|
`(,(regexp-opt '("distinct") 'symbols) . font-lock-keyword-face)
|
|
;; Use-list order directives
|
|
`(,(regexp-opt '("uselistorder" "uselistorder_bb") 'symbols) . font-lock-keyword-face))
|
|
"Syntax highlighting for LLVM.")
|
|
|
|
;; Emacs 23 compatibility.
|
|
(defalias 'llvm-mode-prog-mode
|
|
(if (fboundp 'prog-mode)
|
|
'prog-mode
|
|
'fundamental-mode))
|
|
|
|
;;;###autoload
|
|
(define-derived-mode llvm-mode llvm-mode-prog-mode "LLVM"
|
|
"Major mode for editing LLVM source files.
|
|
\\{llvm-mode-map}
|
|
Runs `llvm-mode-hook' on startup."
|
|
(setq font-lock-defaults `(llvm-font-lock-keywords))
|
|
(setq comment-start ";"))
|
|
|
|
;; Associate .ll files with llvm-mode
|
|
;;;###autoload
|
|
(add-to-list 'auto-mode-alist (cons (purecopy "\\.ll\\'") 'llvm-mode))
|
|
|
|
(provide 'llvm-mode)
|
|
|
|
;;; llvm-mode.el ends here
|